Запрос не возвращает результата (Delphi, Oracle, DBExpress)

В вашем коде есть пара недостатков.

Во-первых, вам не нужен IsEmpty, и вам не нужен ни один вызов First. Когда вы впервые открываете запрос, набор данных автоматически устанавливается в первой строке, и вы можете опустить IsEmpty, если знаете, что собираетесь перебирать строки.

Во-вторых, никогда не SELECT без предложения WHERE, а затем фильтровать данные. Единственная причина использовать SELECT без WHERE - это если вы абсолютно уверены, что вам нужна каждая строка (и столбец) из таблицы. Если вы этого не сделаете, добавьте WHERE, чтобы ограничить количество строк, возвращаемых сервером (и избежать необходимости писать так много кода для его фильтрации на стороне клиента).

Попробуйте вместо этого что-нибудь подобное. Я не знаю, что такое тип данных Fields[2] или Frame11.ID, поэтому я буду рассматривать их как string, как это делает ваш существующий код. Если это не строки, измените обе ссылки на фактический необходимый тип данных. Я также собираюсь предположить, что Fields[2].FieldName равно ID; опять же, если это не так, измените код соответствующим образом.

procedure TFormOperator.TabSheetShowPapersShow(Sender: TObject);
var
  GridRow: Integer;
begin
  SQLQueryShowPapers.SQL.Text := 'SELECT * FROM papers WHERE ID = :ID';
  SQLQueryShowPapers.Parameters.ParamByName('ID').Value := Frame11.ID;
  SQLQueryShowPapers.Open;  // No need for First. Happens automatically

  StringGridShowPapers.RowCount := 1;

  // No need for IsEmpty. If no rows were returned, this loop will not be entered
  while not SQLQueryShowPapers.EOF do
  begin
    StringGridShowPapers.RowCount := StringGridShowPapers.RowCount + 1;
    GridRow := StringGridShowPapers.RowCount - 1;

    StringGridShowPapers.Cells[0, GridRow] := SQLQueryShowPapers.Fields[0].AsString;
    StringGridShowPapers.Cells[1, GridRow] := SQLQueryShowPapers.Fields[1].AsString;
    StringGridShowPapers.Cells[2, GridRow] := SQLQueryShowPapers.Fields[2].AsString;
    SQLQueryShowPapers.Next;
  end;
end;

Кроме того, я бы сделал пару вещей:

• Самое главное, прекратите использовать SELECT * и фактически перечислите нужные столбцы. Код легче поддерживать, и это снижает накладные расходы на перемещение данных с сервера по сети, которые вы не собираетесь использовать.

• Также прекратите использовать жестко запрограммированные ссылки на позиции полей (Fields[0], Fields[1] и т. Д.). Он подвержен ошибкам, он укусит вас сзади, когда столбец изменится в будущем, и это делает невозможным поддержание кода через 6 месяцев, когда вы не помните точно, в каком порядке столбцы находятся, или кому-то еще нужно работать с вашим кодом. Либо добавьте в запрос постоянные поля, либо используйте FieldByName, чтобы получить их по имени.

• Сократите имена переменных, чтобы не печатать. SQLQueryShowPapers, например, может быть просто QryPapers (если у вас нет другого типа запроса, кроме SQL-запроса), а StringGridShowPapers может быть GridPapers или PaperGrid.

• Вы заметите, что я добавил локальную целочисленную переменную GridRow, чтобы уменьшить набор текста, необходимый для всех повторных вызовов, до StringGridShowPapers.RowCount - 1 при каждом доступе к Cells.

• Вы также заметите, что я упростил добавление новых строк в StringGridShowPapers в цикле.

• Я также устранил необходимость тестирования Fields[0].AsString = Frame11.ID, добавив параметр и предложение WHERE в ваш оператор SQL. Это также уменьшает объем данных, которые должны передаваться с сервера по сети, снижает требования к памяти вашего приложения и сокращает количество времени, которое вы тратите без необходимости на чтение строк, которые вы не будете использовать, и их пропуск (итерации через петля). Другими словами, я удалил весь if тест.

• Наконец, вы можете сократить весь этот код до трех строк (установка SQL.Text, присвоение значения параметру и открытие запроса), если вы полностью избавились от TStringGrid и использовали вместо него TDBGrid. Он специально разработан для отображения данных из набора данных. Все, что вы делаете, - это добавляете TDBGrid в свою форму вместо TStringGrid, также отбрасываете TDataSource, подключаете TDBGrid.DataSource to theTDataSourceand theTDataSource.DataSet` к вашему запросу. Затем откройте свой запрос как обычно, и сетка автоматически заполнится данными без строк кода.

попробуйте это, оператор next находится вне блока if Я думаю, что что-то в ваших данных не позволяет завершить цикл

procedure TFormOperator.TabSheetShowPapersShow(Sender: TObject);
begin
    SQLQueryShowPapers.SQL.Text := 'SELECT * FROM papers';
    SQLQueryShowPapers.Open;
    SQLQueryShowPapers.First;

    if (NOT SQLQueryShowPapers.IsEmpty) then begin
        SQLQueryShowPapers.First;
        StringGridShowPapers.RowCount := 2;

        while (NOT SQLQueryShowPapers.EOF) do begin
            if (SQLQueryShowPapers.Fields[2].AsString = Frame11.ID) then begin
                with StringGridShowPapers do begin
                  Cells[0, (StringGridShowPapers.RowCount - 1)] :=
                    SQLQueryShowPapers.Fields[0].AsString;
                  Cells[1, (StringGridShowPapers.RowCount - 1)] :=
                    SQLQueryShowPapers.Fields[1].AsString;
                  Cells[2, (StringGridShowPapers.RowCount - 1)] :=
                    SQLQueryShowPapers.Fields[2].AsString;
                end;
                StringGridShowPapers.RowCount := StringGridShowPapers.RowCount + 1;
            end;
             SQLQueryShowPapers.Next;
        end;
    end;

end;